I think this will do what you want, please check it out and let me know.
( item 0 of it as string & "$x$" &
item 1 of it as string & "$x$" &
item 2 of it as string & "$x$" &
item 3 of it as string & "$x$" &
(if (year of it as integer = 1980)
then ("<none>")
else
(year of it as string & "/" &
(month of it as two digits) as string & "/" &
(day_of_month of it as two digits) as string) )
of (item 4 of it as date) & "$x$" &
item 5 of it as string )
of (
(if (size of item 1 of it > 0) /* if applicable computers exist */
then (concatenations "%0A" of (names of elements of item 1 of it ))
else ("<none>")),
(if (exists Name of item 0 of it| false)
then (concatenations "%0A" of (Name of item 0 of it as string))
else ("<none>")),
(if (exists Source Severity of item 0 of it| false)
then (concatenations "%0A" of (Source Severity of item 0 of it as string))
else ("<none>")),
(if (exists Category of item 0 of it| false)
then (concatenations "%0A" of (Category of item 0 of it as string))
else ("<none>")),
(if (exists Source Release Date of item 0 of it)
then (Source Release Date of item 0 of it as string)
else ("Fri, 15 Feb 1980")),
(if (exists CVE ID List of item 0 of it | false)
then (concatenations "%0A" of (CVE ID List of item 0 of it as string))
else ("<none>")))
of
(
/* a fixlet */
item 0 of it
/* set of applicable computers for the fixlet, filtered to only the group members we want */
, intersection of (applicable computer set of item 0 of it; item 1 of it)
)
of
(
/* unwrap the set of fixlets */
elements of item 0 of it
/* the set of bes computers in which we are interested */
, item 1 of it
)
of
(
/* Set of fixlets in which we are interested in; filter here for best efficiency */
set of fixlets whose (
applicable computer count of it > 0
AND
(category of it = "Security Update" OR category of it = "Security Hotfix")
AND
Source Severity of it as lowercase does not contain "unspecified"
AND
name of it as lowercase does not contain "superseded")
of bes sites whose(name of it is contained by "Enterprise Security|Updates for Windows Applications")
/* Set of bes computers in which we are interested; filter here for best efficiency */
, member set of bes computer groups whose (name of it = "Production_Site_Computers")
)